TraderR0BERT

Ichimoku Timeframe 3.0

7156 obejrzeń
1478
7156 16
Ichimoku Cloud with
- Tenkan/Kijun Alerts and
- Kumo Breakout Alerts
Usuń z Ulubionych Skryptów Dodaj do Ulubionych Skryptów
//Created by @TraderR0BERT, NETWORTHIE.COM, last updated 03/28/2016
//Ichimoku Cloud Indicator
//Resolution input option for higher/lower time frames
//Alerts for common ichimoku trading signals

study(title="Ichimoku Timeframe 3.0", shorttitle="Ichimoku TF 3.0", overlay=true)

Ten = input(18, minval=1, title="Tenkan")
Kij = input(52, minval=1, title="Kijun")
LeadSpan = input(104, minval=1, title="Senkou B")
Displace = input(52, minval=1, title="Senkou A")
SpanOffset = input(52, minval=1, title="Span Offset")

timeframe = input(title="Timeframe", type=resolution, defval="60")
sts = input(false, title="Show Tenkan")
sks = input(false, title="Show Kijun")
ssa = input(true, title="Show Span A")
ssb = input(true, title="Show Span B")

source = close

//Script for Ichimoku Indicator
donchian(len) => avg(lowest(len), highest(len))
TS = donchian(Ten)
KS = donchian(Kij)
SpanA = avg(TS, KS)
SpanB = donchian(LeadSpan)
SpanAA = avg(TS, KS)[SpanOffset]
SpanBB = donchian(LeadSpan)[SpanOffset]

//Script for Timeframe Optionality
TSTF = security(tickerid, timeframe, TS)
KSTF = security(tickerid, timeframe, KS)

//plot for Tenkan and Kijun (Current Timeframe)
p1= plot(sts and TS ? TS : na, title="Tenkan", linewidth = 2, color = gray)
p2 = plot(sks and KS ? KS : na, title="Kijun", linewidth = 2, color = black)
p3 = plot(ssa and SpanA ? SpanA : na, title="SpanA", linewidth=2, offset=Displace, color=green)
p4 = plot(ssb and SpanB ? SpanB : na, title="SpanB", linewidth=2, offset=Displace, color=red)
p5 = plot(close, title="Chikou", linewidth = 2, offset=-Displace, color = orange)

//plot for Tenkan and Kijun (Timeframe Optionality)
p6 = plot(sts and TSTF ? TSTF : na, title="Tenkan TF", linewidth = 3, color = gray)
p7 = plot(sks and KSTF ? KSTF : na, title="Kijun TF", linewidth=3, color = black)

fill(p3, p4, color = gray, transp = 70, title="Kumo Cloud")

//Crosses Tenkan and Kijun (Arrows)
crossUpTSKS = TS[1] < KS[1] and TS > KS ? 1 : 0
crossDnTSKS = TS[1] > KS[1] and TS < KS ? 1 : 0
cupA = crossUpTSKS == 1 ? crossUpTSKS : 0
cdnA = crossDnTSKS == 1 ? crossDnTSKS : 0

//Plots Tenkan and Kijun Cross
plotarrow(cupA, title="CrossUp Tenkan Kinjun", colorup=green, maxheight=90, minheight=50, transp=0)
plotarrow(cdnA*-1, title="CrossDn Tenkan Kinjun", colordown=red, maxheight=90, minheight=50, transp=0)

//TS & KS Cross Alerts
TSKS_Cross = cross(TS, KS)
TSKS_Cross_TF = cross(TSTF, KSTF)
alertcondition(TSKS_Cross, title="Tenkan Kijun Cross", message="TS & KS Crossing")
alertcondition(TSKS_Cross_TF, title="Tenkan Kijun TF Cross", message="TS & KS TF Crossing")

//Kumo Breakout (Long)
SpanA_Top = SpanAA > SpanBB ? 1 : 0
SpanB_Top = SpanBB > SpanAA ? 1 : 0

LongSpanA = SpanAA > SpanBB and source[1] < SpanAA[1] and source > SpanAA ? 1 : 0
LongSpanB = SpanBB > SpanAA and source[1] < SpanBB[1] and source > SpanBB ? 1 : 0
cupB = LongSpanA == 1 ? LongSpanA : 0
cdnB = LongSpanB == 1 ? LongSpanB : 0

//Kumo Breakout (Long)
plotarrow(cupB, title="Kumo Breakout A-Long", colorup=green, maxheight=90)
plotarrow(cdnB, title="Kumo Breakout B-Long", colorup=green, maxheight=90)

//Kumo Breakout (Long) Alerts
LongSpanA_Cross = SpanA_Top ==1 and crossover(source, SpanAA)
alertcondition(LongSpanA_Cross, title="Kumo Breakout A-Long", message="Kumo Long")
LongSpanB_Cross = SpanB_Top ==1 and crossover(source, SpanBB)
alertcondition(LongSpanB_Cross, title="Kumo Breakout B-Long", message="Kumo Long")

//Kumo Breakout (Short)
ShortSpanA = SpanBB > SpanAA and source[1] > SpanAA[1] and source < SpanAA ? 1 : 0
ShortSpanB = SpanAA > SpanBB and source[1] > SpanBB[1] and source < SpanBB ? 1 : 0
cdnC = ShortSpanA == 1 ? ShortSpanA : 0
cupC = ShortSpanB == 1 ? ShortSpanB : 0

//Kumo Breakout (Short)
plotarrow(cdnC*-1, title="Kumo Breakout A-Short", colordown=red, maxheight=90)
plotarrow(cupC*-1, title="Kumo Breakout B-Short", colordown=red, maxheight=90)

//Kumo Breakout (Short) Alerts
ShortSpanB_Cross = SpanA_Top ==1 and crossunder(source, SpanBB)
alertcondition(ShortSpanB_Cross, title="Kumo Breakout B-Short", message="Kumo Short")
ShortSpanA_Cross = SpanB_Top ==1 and crossunder(source, SpanAA)
alertcondition(ShortSpanA_Cross, title="Kumo Breakout A-Short", message="Kumo Short")
You did an awesome work here Ichimoku.
Odpowiedź
Good day and thank you for the work on this indicator. Do you think this can be modified so that you can have two ichimoku setting on the same screen? I am looking for a way to have the 4H hour and the Daily Ichimoku setting on one chart or 1Hour and 4Hour ichmoku on a chart Like I had on my fxcm platform.
Odpowiedź
Great indicator. I was wondering, what's your reasoning behind changing the ichi from its standard settings to the settings you've chosen? This isn't a loaded question or anything. I just can't find anything online that discusses the settings you've used, and I was wondering what made you think to change the settings. Thanks!
Odpowiedź
TraderR0BERT Sigep1901dl
@sigep1901dl, hey, i don't see that as a loaded question. you're just asking. So I doubled the normal settings. A very successful ichimoku trader (Stocks), called TriforceTrader actually uses these settings. I find them to be more reliable as the breakouts from the clouds are much more meaningful breakouts. you should google TriforceTrader and read some of his stuff. Millionaire trader, and he's probably 26 years old.
Odpowiedź
Sigep1901dl TraderR0BERT
Thanks so much for responding so quickly Robert. The signals definitely work for my purpose, and now its nice to know 'why', instead of blindly following something. I trade forex, but also do some binaries on Nadex, and the signals here provide very high probability when I'm on a 15M chart. Also, I'll definitely check out Triforce Trader too.
Odpowiedź
A more updated version of this Indicator for those interested

Odpowiedź
Robert; Above the cloud will be a better option, as above the price could be below the cloud and above price, which still bearish, but above the cloud ti could be bullish. Not sure if possible above cloud and above price, as the 26, 52, settings in the future may not work properly. But again, above the cloud will be ok.
Odpowiedź
Robert; Could you make an update or create a line of code to change the Chikou color once crosses above the cloud? Thanks.
Odpowiedź
TraderR0BERT telepatico
@telepatico, that's actually a really good idea. I could make the color "dynamic" based on whether or not the Chikou is above the cloud or below the cloud, or even above/below price. Let me know what you think is the best idea.
Odpowiedź
Update coming on the way for this script, where i've simplified the Kumo Breakout Alert script and added an Alert for the Kumo Twist. Keep ya posted.
Odpowiedź
Strona główna Skaner akcji Skaner Forex Skaner Krypto Kalendarz ekonomiczny Show Jak to działa Funkcje wykresów Cena Poleć przyjaciela Dobre Praktyki Centrum Pomocy Rozwiązania internetowe i brokerskie Widżety Wykresy Lekka Biblioteka Wykresów Blog i wiadomości Twitter
Profil Ustawienia profilu Konto i płatności Poleć przyjaciela Wiadomości do działu obsługi Centrum Pomocy Opublikowane Pomysły Obserwujący Lista obserwowanych Wiadomość prywatna Czat Wyloguj